Named arguments on Perl5. Sorta.

broquaint on 2005-10-04T14:16:39

Here's a little bit of madness I cooked up for using named arguments natively in perl5:

use strict;
use warnings;

use PadWalker 'peek_sub';
use List::Util 'first';

## Map named arguments to variables of those names.
sub getargs {
  my %args = do { package DB; () = caller 1; @DB::args };
  my $vals = peek_sub \&{(caller 1)[3]};
  my %res  = map { $_ => $args{substr($_, 1)} }
             grep exists $args{substr($_, 1)}, keys %$vals;
  my %map  = map {
    my $orig_arg  = \$_;
    my($ref_name) = first { $orig_arg == $vals->{$_} } keys %$vals;
    $ref_name => $orig_arg;
  } @_;

  ${ $map{$_} } = $res{$_}
    for keys %res;

  return \%res;
}

## Basic test of getargs();
sub foo {
  getargs my($this, $that, $theother);
  print "this is: $this\nthat is: $that\nand the other is: $theother\n";
}

## Have these pairs mapped to variables of the same name.
foo this     => "an argument",
    that     => "used to refer to things",
    theother => "is something else altogether";

This will output:

this is: an argument
that is: used to refer to things
and the other is: is something else altogether

So, as you can see, given a list of pairs the variable names matching the keys will be automagically assigned to the corresponding values.

I'd had it in the back of my mind that this could be achieved fairly simply, as demonstrated above, but as you can see it's not the most robust of methods. I'll CPAN-ify it if anyone wants a rather more sensible version of the code, and I'm sure documentation and tests wouldn't go amiss too.

---

I approve of your madness

drhyde on 2005-10-04T14:29:01

You are a sick sick man. Well done.

Re:

Aristotle on 2005-10-06T08:06:05

I don’t think it’s at all crazy or mad. Good job! Looking forward to the module.

Sub::Signatures?

clscott on 2005-10-07T05:00:04

Have you seen Sub::Signatures?

http://use.perl.org/user/Ovid/journal/27053